OrCAD PSpice. Анализ электрических цепей

Модель биполярного транзистора для высоких частот

Для анализа схем ОЭ мы часто используем гибридную π-модель. На рис. 3.35 показана эта модель с внешними компонентами V_s, R_s, и R_L. В эту модель введен дополнительный узел В', чтобы отразить поведение транзистора на высоких частотах. Элементы, используемые в этой модели: резисторы r_ce, r_bb', r_b'e и r_b'c и конденсаторы С_с и С_е. Коэффициент усиления представляется источником тока, управляемым напряжением (ИТУН), g_mV_b'e. На рис. 3.35 показаны значения, используемые в этом примере. Они соответствуют следующему входному файлу:

High-Frequency Model of Bipolar-Junction Transistor

VS 1 0 AC 1mV

G 4 0 3 0 50mS

RS 1 2 50

RBB 2 3 100

RBE 3 0 1k

RBC 3 4 4 MEG

RCE 4 0 80k

RL 4 0 2k

CE 3 0 100pF

CC 3 4 3pF

.AC DEC 50 100k 10MEG

.PROBE

.END

Рис. 3.35. Гибридная π-модель биполярного транзистора 

Выполните анализ и определите выходное напряжение на средних частотах V(4). Убедитесь, что оно приблизительно равно 85 мВ. Затем получите график

20·lg(V(4)/84,5мВ).

График показан на рис. 3.36. Он позволит вам найти точку, соответствующую 3 дБ. Убедитесь, что при этом частота равна f=2,8 МГц.

Рис. 3.36. Выходной файл для рис. 3.35

Трудно получить уравнения, необходимые для правильного решения задач такого типа, и решить их, поскольку схема имеет четыре независимых узла и содержит сложные элементы. В данном случае применение такого мощного инструмента, как PSpice, совершенно оправдано. Если нет необходимости в большой точности расчетов, то вместо этого часто используются более простые модели.

Эмиттерный повторитель при работе на высоких частотах

Рассмотрим теперь другую разновидность высокочастотного анализа. Эта схема включает полное сопротивление нагрузки Z_L, состоящее из R_L и C_L. Усилитель имеет низкое выходное сопротивление и используется как драйвер для емкостной нагрузки. На рис. 3.37 показана схема с гибридной π-моделью. Отметим, что стрелка тока внутри источника G по-прежнему направлена к эмиттерному узлу. Входной файл имеет вид:

Emitter Follower High-Frequency Model

VS 1 0 AC 1mV

G 0 4 3 4 50mS

RS 1 2 50

RBB 2 3 100

RBE 3 4 1k

RBC 3 0 4MEG

RL 4 0 2k

CL 4 0 3nF

CC 3 0 3pF

CE 3 4 100pF

.AC DEC 50 100k 10MEG

.PROBE

.END

Рис. 3.37. Гибридная π-модель эмиттерного повторителя с емкостной нагрузкой

Выполните анализ, затем получите график для V(4). Обратите внимание, что коэффициент усиления немного меньше единицы, как и ожидается для эмиттерного повторителя. Чтобы получить график Боде, используйте функцию

20·lg(V(4)/0.99мВ).

Затем используйте курсор, чтобы проверить, что значение 3 дБ достигается при f=2,7 МГц. Добавьте второй график, который является графиком фазового угла напряжения V(4). Сделайте это, просто получив график VP(4). Убедитесь, что при частоте, соответствующей 3 дБ, значение фазового угла приблизительно равно -57°. Обратите внимание, что при 100 кГц — самой низкой частоте, отображенной на графике, уже имеется некоторый фазовый угол из-за емкостного характера нагрузки. На рис. 3.38 показаны фазовый угол и графики Боде для этой схемы.

Рис. 3.38. Выходной файл для схемы на рис. 3.37

Чувствительность по постоянному току

Изменения параметров элементов в таких схемах могут привести к неправильной работе устройства. В некоторых случаях ожидаемые напряжения и токи выходят за пределы приемлемых значений. В других случаях неверно выбранное смещение может привести к искажениям и так далее. При использовании PSpice чувствительность выходного напряжения к изменениям параметров может быть определена введением во входной файл команды .SENS.

Например, в последовательной цепочке, показанной на рис. 3.39, резистор R₂ представляет собой сопротивление нагрузки. Напряжение на этом резисторе составляет 1,25 В. Входной файл содержит команду, позволяющую определить чувствительность этого напряжения относительно других элементов схемы:

Sensitivity of Load Voltage in Series Circuit

Vs 1 0 5V

R1 1 2 300

R2 2 0 100

.sens V(2)

.end

Рис. 3.39. Схема для иллюстрации понятия чувствительности