Windows Script Host для Windows 2000/XP

s="Всего аргументов: "+objArgs.Count()+"\n";

for (i=0; i<=objArgs.Count()-1; i++)

 s+=objArgs(i)+"\n"; //Формируем строки со значениями аргументов

objUnnamedArgs=objArgs.Unnamed;  //Создаем объект WshUnnamed

//Определяем количество безымянных аргументов

s+="\nБезымянных аргументов: "+objUnnamedArgs.length+"\n";

for (i=0; i<=objUnnamedArgs.length-1; i++)

 //Формируем строки со значениями безымянных аргументов

 s+=objUnnamedArgs(i)+"\n";

objNamedArgs=objArgs.Named; //Создаем объект WshNamed

//Определяем количество именных аргументов

s+="\nИменных аргументов: "+objNamedArgs.length+"\n";

//Проверяем, существует ли аргумент /Имя:

if (objNamedArgs.Exists("Имя")) s+=objNamedArgs("Имя")+"\n";

//Проверяем, существует ли аргумент /Comp:

if (objNamedArgs.Exists("Comp")) s+=objNamedArgs("Comp")+"\n";

WScript.Echo(s);  //Выводим сформированные строки

/*************  Конец *********************************************/

Листинг 2.22. Доступ к параметрам командной строки запущенного сценария (VBScript)

'********************************************************************

' Имя: Args.vbs

' Язык: VBScript

' Описание: Работа с аргументами запущенного сценария

'********************************************************************

Option Explicit

Dim i,Arg,objArgs,s,objNamedArgs,objUnnamedArgs  ' Объявляем переменные

Set objArgs = WScript.Arguments  ' Создаем объект WshArguments

' Определяем общее количество аргументов

s="Всего аргументов: " & objArgs.Count() & vbCrLf

For Each Arg In objArgs

 s=s & Arg & vbCrLf  ' Формируем строки со значениями аргументов

Next

Set objUnnamedArgs=objArgs.Unnamed  ' Создаем объект WshUnnamed

' Определяем количество безымянных аргументов

s=s & vbCrLf & "Безымянных аргументов: " & objUnnamedArgs.length & vbCrLf

For Each Arg In objUnnamedArgs

 ' Формируем строки со значениями безымянных аргументов

 s=s & Arg & vbCrLf

Next

Set objNamedArgs=objArgs.Named  ' Создаем объект WshNamed

' Определяем количество именных аргументов

s=s & vbCrLf & "Именных аргументов: " & objNamedArgs.Length & vbCrLf

' Проверяем, существует ли аргумент /Имя:

If objNamedArgs.Exists("Имя") Then

 s=s & objNamedArgs("Имя") & vbCrLf

End If

' Проверяем, существует ли аргумент /Comp:

If objNamedArgs.Exists("Comp") Then

 s=s & objNamedArgs("Comp") & vbCrLf

End If

WScript.Echo s   ' Выводим сформированные строки

'*************  Конец *********************************************

Выход из сценария с определенным кодом завершения

Любое приложение при завершении своей работы может возвращать операционной системе целое число — код выхода (обычно ненулевое значение этого кода указывает на то, что выполнение программы прервалось в силу той или иной ошибки).